;*************************************************
; overlays grid of apex coordinates
;************************************************
load "$NCARG_ROOT/lib/ncarg/nclscripts/csm/gsn_code.ncl"   
load "$NCARG_ROOT/lib/ncarg/nclscripts/csm/gsn_csm.ncl"    
load "/home/tgcm/ncl/web_ex/func_lib/halfzp2full.ncl"
;************************************************
begin
;************************************************
; before the data can be plotted, there is a 
; sequence of things that have to be done to it:
;************************************************
  in    = addfile("/chewy/d/murphys/files/smarch_migsdi_c_1.nc","r")
  x     = in->TN                              ; read in data
  x     = halfzp("TN",x)                      ; convert to full zp
  ut    = in->ut                              ; required for local time axis

  l2plt = 8                                   ; level index to plot
  t2plt = 2                                   ; time  index to plot
;************************************************
; create plot
;************************************************
  wks = gsn_open_wks("ps" ,"ce")              ; open a ps file
  gsn_define_colormap(wks,"BlAqGrYeOrRevi200" ) 

  res                          = True         ; plot mods desired
  res@gsnCenterString          = "UT = "+ut(t2plt)+" zplev= "+x&lev(l2plt)
  res@tiMainString             = "Apex Overlay"
  res@cnFillOn                 = True         ; add color
  res@gsnSpreadColors          = True         ; use full range of color map
  res@lbLabelAutoStride        = True         ; nice lb labels
  res@mpFillOn                 = False        ; turn off map fill
  res@gsnDraw                  = False        ; don't draw yet
  res@gsnFrame                 = False        ; don't advance frame yet

  plot = gsn_csm_contour_map_ce(wks,x(t2plt,l2plt,:,:), res)
;************************************************
; read in apex data and create apex overlay
;************************************************
  apex_in = addfile("/home/tgcm/ncl/web_ex/dataP/apex/apex.nc","r")
  apex_lat = apex_in->apex_lat
  apex_lon = apex_in->apex_lon

  conres                = True
  conres@gsnDraw        = False
  conres@gsnFrame       = False
  conres@cnInfoLabelOn  = False
  conres@cnLineLabelsOn = False
  conres@cnLineColor    = (/0.8,0.8,0.8/)
  plotlon = gsn_csm_contour(wks,apex_lon,conres)  ; create contours of apexlon
  plotlat = gsn_csm_contour(wks,apex_lat,conres)  ; create contours of apexlat
  overlay(plotlat,plotlon)                        ; make these one overlay

  overlay(plot,plotlat)                           ; put apex overlay on map

  draw(plot)
  frame(wks)
end